Merge branch 'feature/workadventure' into 'main'

Simple Workadventure on void.hacc.space

See merge request hacc/infra/haccfiles!31

hosts/hainich/configuration.nix

@@ -18,6 +18,7 @@
     ./services/hasenloch.nix
     ./services/syncthing.nix
     ./services/monitoring.nix
+    ./services/workadventure.nix
   ];
   boot.loader.grub.enable = true;
   boot.loader.grub.version = 2;

hosts/hainich/services/workadventure.nix

@@ -0,0 +1,111 @@
+{pkgs, lib, config, ...}:
+
+let
+  wa-container-ip = "fd00::42:16";
+  # this is a static "secret" that is also compiled into workadventure,
+  # so it seems ok to put it into the nix store
+  coturn-auth-secret = "990bc6fc68c720a9159f9c7613b2dcc3cc9ffb4f";
+  # domain on which workadventure is served
+  domain = "turn.hacc.space";
+
+
+  # FUNFACT:
+  # the nixos-container module is sufficiently broken that if you move these
+  # fetchgits into the container config below, Nix will run into infinite recursion!
+  
+  # contains the hacc assembly map
+  haccpkgssrc = pkgs.fetchgit {
+    url = "https://gitlab.infra4future.de/stuebinm/workadventure-nix-hacc";
+    rev = "23a085b0386595f9e769ef3c182749cecc342ead";
+    sha256 = "199np37dkhk52lsjw0f9x2h9vfi800s18gk5pfijs6pc1hr11scd";
+  };
+  # contains the workadventure module
+  fediventure = pkgs.fetchgit {
+    url = "https://gitlab.infra4future.de/stuebinm/fediventure-simple";
+    rev = "2d1361f9e96e17f1a5b1de7cb75b45ed4dd1b177";
+    sha256 = "1rfyrqwlallkxgn64cd1jwa00gyig5r5xm0irfsq10jkvfsc0v5i";
+  };
+  haccpkgs = (import "${haccpkgssrc}/default.nix") {inherit pkgs lib;};
+
+in
+{
+  # not the most intuitive of container names, but "workadventure" is too long
+  containers.wa-void = {
+    
+    config = {config, pkgs, ...}: {
+        imports = [ "${fediventure}/workadventure.nix" ];
+        networking.firewall.allowedTCPPorts = [ 80 ];
+
+        services.workadventure."void.hacc.space" = {
+          nginx = {
+            default = true;
+            inherit domain;
+          };
+          
+          frontend.startRoomUrl = "/_/global/void.hacc.space/maps/main.json";
+          
+          
+          commonConfig = {
+            webrtc.stun.url = "stun:turn.hacc.space:3478";
+            webrtc.turn = {
+              url = "turn:95.217.159.23";
+              user = "turn";
+              password = coturn-auth-secret;
+            };
+            jitsi.url = "meet.ffmuc.net";
+          };
+        };
+      };
+    
+    privateNetwork = true;
+    hostAddress6 = "fd00::42:14";
+    localAddress6 = wa-container-ip;
+
+    autoStart = true;
+
+  };
+  
+  services.coturn = {
+    enable = true;
+    realm = "turn.hacc.space";
+    static-auth-secret = coturn-auth-secret;
+    use-auth-secret = true;
+    no-cli = true;
+    no-tcp-relay = true;
+
+    cert = config.security.acme.certs."turn.hacc.space".directory + "full.pem";
+    pkey = config.security.acme.certs."turn.hacc.space".directory + "key.pem";
+  };
+
+  
+  services.nginx = {
+    virtualHosts."void.hacc.space" = {
+      forceSSL = true;
+      enableACME = true;
+      locations."/" = {
+        proxyPass = "http://[${wa-container-ip}]";
+        proxyWebsockets = true;
+      };
+    };
+    # this isn't actually needed, but acme requires a webserver to serve
+    # challanges, so I guess it's easier to just define a virtualHost here
+    virtualHosts."turn.hacc.space" = {
+      enableACME = true;
+      forceSSL = true;
+    };
+  };
+  
+
+  networking.firewall = with config.services.coturn;
+    let 
+      ports = [ listening-port tls-listening-port ];
+    in {
+      allowedTCPPorts = [ 80 ] ++ ports;
+      allowedUDPPorts = ports;
+      allowedUDPPortRanges = [
+        { from = min-port; to = max-port; }
+      ];
+    };
+
+}
+