haccfiles/pkgs/default.nix

{ config ? {}, system ? builtins.currentSystem, ... }@args:

let
  sources = import ../nix/sources.nix;
  pkgs = import sources.nixpkgs args;
  unstable = import sources.nixpkgs-unstable args;

  callPackage = pkgs.lib.callPackageWith (pkgs // newpkgs);

  newpkgs = {
    alps = callPackage ./alps {};

    docker = (pkgs.callPackage (pkgs.path + "/pkgs/applications/virtualization/docker") {
      iptables = pkgs.writeScriptBin "iptables" ''
        #!${pkgs.runtimeShell}
        echo docker tried to run the following iptables command: $@
        exit 0
      '';
    }).docker_19_03.overrideAttrs (super: {
      extraPath = super.extraPath + ":${pkgs.zfs}/bin";
    });

    linuxPackagesFor = kernel: (pkgs.linuxPackagesFor kernel).extend (_: ksuper: {
      decklink = callPackage ./decklink { kernel = ksuper.kernel; };
    });

    blackmagicDesktopVideo = callPackage ./blackmagic-desktop-video { };

    obs-studio = unstable.obs-studio.overrideAttrs (_: rec {
      wrapLibraries = with (pkgs // newpkgs); [
        xorg.libX11.out
        libvlc
        blackmagicDesktopVideo
        libcxx
        libcxxabi
      ];
      postInstall = ''
        wrapProgram $out/bin/obs \
          --prefix "LD_LIBRARY_PATH" : "${pkgs.lib.makeLibraryPath wrapLibraries}"
      '';
    });

    inherit (unstable) bottom;
  };

in pkgs.extend(_: _: newpkgs)