haccfiles/pkgs/decklink/default.nix

{ stdenv, requireFile, fetchpatch, kernel, lib }:

stdenv.mkDerivation rec {
  pname = "decklink";
  version = "12.0";

  src = requireFile {
    name = "Blackmagic_Desktop_Video_Linux_12.1.tar.gz";
    url = "https://www.blackmagicdesign.com/support/download/d99c3a1740b546f094ffbb30ddf1f4c1";
    sha256 = "51febf247d22412beea2d637fcc34cc19b1a46df9a5bf0e157d95705bf7c7b73";
  };

  KERNELDIR = "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build";
  INSTALL_MOD_PATH = placeholder "out";

  nativeBuildInputs =  kernel.moduleBuildDependencies;

  setSourceRoot = ''
    tar xf Blackmagic_Desktop_Video_Linux_12.1/other/x86_64/desktopvideo-12.1a9-x86_64.tar.gz
    sourceRoot=$NIX_BUILD_TOP/desktopvideo-12.1a9-x86_64/usr/src
  '';

  buildPhase = ''
    runHook preBuild

    make -C $sourceRoot/blackmagic-12.1a9 -j$NIX_BUILD_CORES
    make -C $sourceRoot/blackmagic-io-12.1a9 -j$NIX_BUILD_CORES

    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall

    make -C $KERNELDIR M=$sourceRoot/blackmagic-12.1a9 modules_install
    make -C $KERNELDIR M=$sourceRoot/blackmagic-io-12.1a9 modules_install

    runHook postInstall
  '';

  meta = with lib; {
    homepage = "https://www.blackmagicdesign.com/support/family/capture-and-playback";
    maintainers = [ maintainers.hexchen ];
    license = licenses.unfree;
    description = "Kernel module for the Blackmagic Design Decklink cards";
    platforms = platforms.linux;
  };
}