haccfiles/pkgs/mattermost/default.nix

{ stdenv, fetchurl, fetchFromGitHub, buildGo118Module, buildEnv, lib, sources }:

let
  version = "7.8.10";

  mattermost-server = buildGo118Module rec {
    pname = "mattermost-server";
    inherit version;

    src = sources.mattermost-server.outPath;

    vendorSha256 = "sha256-VvGLYOESyoBpFmIibHWxazliHcscMxf3KcQ46NQ4syk=";

    subPackages = [ "cmd/mattermost" ];

    ldflags = [
	"-s"
	"-w"
        "-X github.com/mattermost/mattermost-server/model.BuildNumber=nixpkgs-${version}"
    ];

  };

  mattermost-webapp = stdenv.mkDerivation {
    pname = "mattermost-webapp";
    inherit version;

    src = sources.mattermost-webapp;

    installPhase = ''
      mkdir -p $out
      cp -r client $out
      cp -r i18n $out
      cp -r fonts $out
      cp -r templates $out
      cp -r config $out
    '';
  };

in
  buildEnv {
    name = "mattermost-${version}";
    paths = [ mattermost-server mattermost-webapp ];

    meta = with lib; {
      description = "Open-source, self-hosted Slack-alternative";
      homepage = "https://www.mattermost.org";
      license = with licenses; [ agpl3 asl20 ];
      maintainers = with maintainers; [ fpletz ryantm ];
      platforms = platforms.unix;
    };
  }