{ config ? {}, system ? builtins.currentSystem, ... }@args:

let
  sources = import ../nix/sources.nix;
  pkgs = import sources.nixpkgs args;

  callPackage = pkgs.lib.callPackageWith (pkgs // newpkgs);

  newpkgs = {
    alps = callPackage ./alps {};

    docker = pkgs.docker.overrideAttrs (super: {
      extraPath = super.extraPath + ":${pkgs.zfs}/bin";
    });

    dns = import (pkgs.fetchFromGitHub {
      owner = "kirelagin";
      repo = "nix-dns";
      rev = "v0.3.1";
      sha256 = "1ykmx6b7al1sh397spnpqis7c9bp0yfmgxxp3v3j7qq45fa5fs09";
    } + "/dns") { inherit pkgs; };

    linuxPackagesFor = kernel: (pkgs.linuxPackagesFor kernel).extend (_: ksuper: {
      decklink = callPackage ./decklink { kernel = ksuper.kernel; };
    });

    blackmagicDesktopVideo = callPackage ./blackmagic-desktop-video { };

    obs-studio = pkgs.obs-studio.overrideAttrs (_: rec {
      wrapLibraries = with (pkgs // newpkgs); [
        xorg.libX11.out
        libvlc
        blackmagicDesktopVideo
        libcxx
        libcxxabi
      ];
      postInstall = ''
        wrapProgram $out/bin/obs \
          --prefix "LD_LIBRARY_PATH" : "${pkgs.lib.makeLibraryPath wrapLibraries}"
      '';
    });
  };

in pkgs.extend(_: _: newpkgs)