{ stdenv, requireFile, fetchpatch, kernel, lib }:

stdenv.mkDerivation rec {
  pname = "decklink";
  version = "12.3";

  src = requireFile {
    name = "Blackmagic_Desktop_Video_Linux_12.3.tar.gz";
    url = "https://www.blackmagicdesign.com/support/";
    sha256 = "1c6m3wb3asbkx45ap523zbsiimrxpsrv3wl1ykxv3njd73zziwyb";
  };

  KERNELDIR = "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build";
  INSTALL_MOD_PATH = placeholder "out";

  nativeBuildInputs =  kernel.moduleBuildDependencies;

  setSourceRoot = ''
    tar xf Blackmagic_Desktop_Video_Linux_12.3/other/x86_64/desktopvideo-12.3a10-x86_64.tar.gz
    sourceRoot=$NIX_BUILD_TOP/desktopvideo-12.3a10-x86_64/usr/src
  '';

  buildPhase = ''
    runHook preBuild

    make -C $sourceRoot/blackmagic-12.3a10 -j$NIX_BUILD_CORES
    make -C $sourceRoot/blackmagic-io-12.3a10 -j$NIX_BUILD_CORES

    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall

    make -C $KERNELDIR M=$sourceRoot/blackmagic-12.3a10 modules_install
    make -C $KERNELDIR M=$sourceRoot/blackmagic-io-12.3a10 modules_install

    runHook postInstall
  '';

  meta = with lib; {
    homepage = "https://www.blackmagicdesign.com/support/family/capture-and-playback";
    maintainers = [ maintainers.hexchen ];
    license = licenses.unfree;
    description = "Kernel module for the Blackmagic Design Decklink cards";
    platforms = platforms.linux;
  };
}